# Maintained by: PJALM for: PJALM ASUS at: Thu Apr 10 09:42:53 UTC 2014
# Patch Name   : ASUS A46CA

# Add the DTGP method
into method label DTGP remove_entry;
into definitionblock code_regex . insert begin
Method (DTGP, 5, NotSerialized)\n
{\n
	If (LEqual (Arg0, Buffer (0x10)\n
		{\n
			/* 0000 */	0xC6, 0xB7, 0xB5, 0xA0, 0x18, 0x13, 0x1C, 0x44,\n
			/* 0008 */	0xB0, 0xC9, 0xFE, 0x69, 0x5E, 0xAF, 0x94, 0x9B\n
		}))\n
	{\n
		If (LEqual (Arg1, One)) {\n
			If (LEqual (Arg2, Zero)) {\n
				Store (Buffer (One) { 0x03 }, Arg4)\n
				Return (One)\n
			}\n
			If (LEqual (Arg2, One)) {\n
				Return (One)\n
			}\n
		}\n
	}\n
	Store (Buffer (One) { 0x00 }, Arg4)\n
	Return (Zero)\n
}
end;

# Add Darwin to the supported operating systems
into method label _INI code_regex \{(\s+)(If\s\(_OSI\s\("Windows\s2001"\)\)) replace_matched begin  {\n
						If (_OSI ("Darwin"))\n
						{\n
							Store (0x2710, OSYS)\n
						}\n
\n
						$2
end;

# ASUS_A46CA Fixes
into_all all code_regex _T_0 replaceall_matched begin T_0 end;
into method label _CRS parent_label PCI0 code_regex CreateDWordField\s\(BUF0,\s\\_SB.PCI0._Y0F._LEN,\sMSLN\) replace_matched begin CreateQWordField (BUF0, \\_SB.PCI0._Y0F._LEN, MSLN) end;
into_all all code_regex pnp0c14 replaceall_matched begin PNP0C14 end;
into method label HSWC parent_label ASHS insert begin Return (Zero) end;

into method label _Q0E parent_label _SB.PCI0.LPCB.EC0 code_regex (If\s\(LNotEqual\s\(\^\^\^GFX0.LCDD._DCS\s\(\),\s0x1F\)\)\s+\{)\s+Return\s\(One\)(\s+\}) replace_matched begin %1%2 end;
into method label _Q0E parent_label _SB.PCI0.LPCB.EC0 code_regex (\s+\^\^\^\^ATKD.IANE\s\(Add\s\(LBTN,\s0x20\)\)\s+\}\s+\})\s+Return\s\(One\) replace_matched begin %1 end;

into method label _Q0F parent_label _SB.PCI0.LPCB.EC0 code_regex (If\s\(LNotEqual\s\(\^\^\^GFX0.LCDD._DCS\s\(\),\s0x1F\)\)\s+\{)\s+Return\s\(One\)(\s+\}) replace_matched begin %1%2 end;
into method label _Q0F parent_label _SB.PCI0.LPCB.EC0 code_regex (\s+\^\^\^\^ATKD.IANE\s\(Add\s\(LBTN,\s0x10\)\)\s+\}\s+\})\s+Return\s\(One\) replace_matched begin %1 end;

into method label _Q11 parent_label _SB.PCI0.LPCB.EC0 code_regex (\s+STB2\s\(0x99\))\s+Return\s\(One\) replace_matched begin %1 end;
into method label _Q13 parent_label _SB.PCI0.LPCB.EC0 code_regex (\s+STB2\s\(0xA0\))\s+Return\s\(One\) replace_matched begin %1 end;
into method label _Q14 parent_label _SB.PCI0.LPCB.EC0 code_regex (\s+STB2\s\(0xAE\))\s+Return\s\(One\) replace_matched begin %1 end;
into method label _Q15 parent_label _SB.PCI0.LPCB.EC0 code_regex (\s+STB2\s\(0xB0\))\s+Return\s\(One\) replace_matched begin %1 end;
into method label RBAT parent_label _SB.PCI0.LPCB.EC0 code_regex (\s+Return\s\(Local1\))\s+Return\s\(Ones\) replace_matched begin %1 end;
into method label WBAT parent_label _SB.PCI0.LPCB.EC0 code_regex (\s+Return\s\(Local1\))\s+Return\s\(Ones\) replace_matched begin %1 end;

into device label COPR set_label begin MATH end;
into_all all code_regex COPR replaceall_matched begin MATH end;

## Method _BCL in LCDD
#into method label _BCL parent_label LCDD code_regex ([\s\S]*) store_%8;
#into method label _BCL parent_label LCDD remove_entry;
#into device label LCDD insert begin Method (_BCL, 0, Serialized)\n{\n} end;
#into method label _BCL parent_label LCDD code_regex .* replace_matched begin %8 end;

## Method MCTH in \
#into method label MCTH parent_label \ code_regex ([\s\S]*) store_%8;
#into method label MCTH parent_label \ remove_entry;
#into scope label \ insert begin Method (MCTH, 2, Serialized)\n{\n} end;
#into method label MCTH parent_label \ code_regex .* replace_matched begin %8 end;

## Method WMNB in ATKD
#into method label WMNB parent_label ATKD code_regex ([\s\S]*) store_%8;
#into method label WMNB parent_label ATKD remove_entry;
#into device label ATKD insert begin Method (WMNB, 3, Serialized)\n{\n} end;
#into method label WMNB parent_label ATKD code_regex .* replace_matched begin %8 end;

## Method BIF9 in _SB.PCI0.LPCB.EC0
#into method label BIF9 parent_label _SB.PCI0.LPCB.EC0 code_regex ([\s\S]*) store_%8;
#into method label BIF9 parent_label _SB.PCI0.LPCB.EC0 remove_entry;
#into scope label _SB.PCI0.LPCB.EC0 insert begin Method (BIF9, 0, Serialized)\n{\n} end;
#into method label BIF9 parent_label _SB.PCI0.LPCB.EC0 code_regex .* replace_matched begin %8 end;

# Add Brightness Control
into device label PNLF parent_label _SB remove_entry;
into scope label _SB insert begin
Device (PNLF)\n
{\n
	Name (_HID, EisaId ("APP0002"))\n
	Name (_CID, "backlight")\n
	Name (_UID, 0x0A)\n
	Name (_STA, 0x0B)\n
}
end;

# Add the missing MCHC device
into device label MCHC parent_label PCI0 remove_entry;
into device label PCI0 insert begin
Device (MCHC)\n
{\n
	Name (_ADR, Zero)\n
}
end;

# Fix the LPC Device
into method label _DSM parent_label LPCB remove_entry;
into device label LPCB insert begin
Method (_DSM, 4, NotSerialized)\n
{\n
	Store (Package (0x02) {\n
		"device-id", Buffer (0x04) {0x44,0x1E,0x00,0x00}\n
	}, Local0)\n
	DTGP (Arg0, Arg1, Arg2, Arg3, RefOf (Local0))\n
	Return (Local0)\n
}
end;

# Fix the SMBUS to allow for loading of the AppleSMBusController.kext
into device label BUS0 parent_label SBUS remove_entry;
into device label SBUS insert begin
Device (BUS0)\n
{\n
	Name (_CID, "smbus")\n
	Name (_ADR, Zero)\n
	Device (DVL0)\n
	{\n
		Name (_ADR, 0x57)\n
		Name (_CID, "diagsvault")\n
		Method (_DSM, 4, NotSerialized)\n
		{\n
			Store (Package (0x02) {\n
				"address", 0x57
			}, Local0)\n
			DTGP (Arg0, Arg1, Arg2, Arg3, RefOf (Local0))\n
			Return (Local0)\n
		}\n
	}\n
}
end;

# Fix HDEF device for the Realtek ALC270 audio codec, edits thanks to Toleda
into method label _DSM parent_label HDEF remove_entry;
into device label HDEF insert begin
Method (_DSM, 4, NotSerialized)\n
{\n
	Store (Package (0x0E) {\n
		"AAPL,slot-name", "Built In",\n
		"name", "Realtek Audio Controller",\n
		"model", Buffer () {"Realtek ALC270 Audio Controller"},\n
		"device_type", Buffer (0x10) {"Audio Controller"},\n
		"layout-id", Buffer (0x04) {0x01,0x00,0x00,0x00},\n
		"PinConfigurations", Buffer (Zero) {},\n
		"hda-gfx", Buffer (0x0A) {"onboard-1"}\n
	}, Local0)\n
	DTGP (Arg0, Arg1, Arg2, Arg3, RefOf (Local0))\n
	Return (Local0)\n
}
end;

# Fixes 'Built-in' status for Realtek Gigabit Ethernet
into method label _DSM parent_label GLAN remove_entry;
into device label GLAN insert begin
Method (_DSM, 4, NotSerialized)\n
{\n
	Store (Package (0x0C) {\n
		"AAPL,slot-name", "Built In",\n
		"name", "Realtek Ethernet Controller",\n
		"model", "Realtek RTL8168F/8111F Gigabit Network Controller",\n
		"device_type", Buffer (0x13) {"Ethernet Controller"},\n
		"built-in", Buffer (One) {0x01},\n
		"location", Buffer (0x02) {"1"}\n
	}, Local0)\n
	DTGP (Arg0, Arg1, Arg2, Arg3, RefOf (Local0))\n
	Return (Local0)\n
}
end;

# Change ID of SATA device for Intel 7 Series Chipset
into device label SAT0 set_label begin SATA end;
into_all all code_regex SAT0 replaceall_matched begin SATA end;
into device label SAT1 remove_entry;
into method label _DSM parent_label SATA remove_entry;
into device label SATA insert begin
Method (_DSM, 4, NotSerialized)\n
{\n
	Store (Package (0x0A) {\n
		"AAPL,slot-name", "Built In",\n
		"name", "Intel AHCI Controller",\n
		"model", Buffer (0x2D) {"Intel 7 Series Chipset Family SATA Controller"},\n
		"device_type", Buffer (0x0F) {"AHCI Controller"},\n
		"device-id", Buffer (0x04) {0x03,0x1E,0x00,0x00}\n
	}, Local0)\n
	DTGP (Arg0, Arg1, Arg2, Arg3, RefOf (Local0))\n
	Return (Local0)\n
}
end;